VI. Miscellaneous Macros

The following are a few other macros that I use – not necessarily hunter-specific – that make little tasks in Azeroth just a bit easier…

Garwulf’s Fishin’ Macro
This is a super-handy-dandy macro I created for some expert angling. This one little macro will equip all of your fishing gear, apply a lure to your pole and even cast it. Just use this same button to fish — when your lure buff expires, the macro will immediately know to reapply a new lure. Customize it to suit your particular fishing gear setup, then have fun fishin’!

#showtooltip Fishing

/equip Mastercraft Kalu’ak Fishing Pole
/equip Weather-Beaten Fishing Hat
/use Weather-Beaten Fishing Hat
/use Fishing
/script UIErrorsFrame:Clear()

Handy Daily Quest Macro
Back in WotLK I grew tired of having to rummage through my inventory each time I needed to use an item for a daily quest, so I created a macro that would cover all of the quest items I’d need to use on a daily basis. My Cataclysm one doesn’t contain nearly as many items, but I still find using it much more convenient than having to open my bags and click on the items every time.

This macro uses the following items: The Tahret Dynasty Mallet for the “Thieving Little Pluckers” quest, the Magnetized Scrap Collector for “Magnets, How Do They Work?”, the Enchanted Salve for “Burn Victims”, and it also places Seaforium Bombs in Strand of the Ancients and Isle of Conquest.

/use item:63351
/use item:62829
/use item:69240
/use item:39213
/use item:46847
/use item:47030

You can add a bunch more lines to this macro – customizing it to suit your needs. To add additional items, just find the item’s ID by searching for it on WoWHead, then add it to the macro. The item ID can be found in your browser’s address bar, like so:

Enchanted Salve
Item ID for Enchanted Salve
Isle of Conquest & Strand of the Ancients Bomb Macro
I don’t always queue for IoC ot SotA, but when I do, I use this macro for easier wall bombing.

/use item:46847
/use item:47030

Simple All-Terrain Mount Macro
This macro checks to see if the area is flyable or not, then selects the fastest method of travel. It also prevents you from hurling yourself into sudden death by accidentally jumping off of your flying mount.

Just substitute the mounts included in the macro with your preferred methods of air and ground travel.

/dismount [mounted,noflying]
/cast [noflyable,nomounted] Dark War Talbuk; [flyable,nomounted] Onyx Netherwing Drake

All-Terrain Mount Macro With Variety
This macro performs the same function as the above macro, but also allows for the usage of more mounts in a predefined sequence. Just replace the example mounts with the ones in your collection and you’re all set. Thanks to Quill2006 for submitting this. 😀

/dismount [mounted,noflying]
/castsequence [flyable] Albino Drake, Bronze Drake, Green Proto-Drake, Argent Hippogryph, Cenarion War Hippogryph; [noflyable] Venomhide Ravasaur, Black War Bear, Black War Talbuk, Cobalt Riding Talbuk, Swift Zhevra

I use an addon called GoGoMount, which handles all of my mount select duties for me. GoGoMount will randomly auto-select the fastest mount available for your current location. This is a fun addon, especially for those who have a multitude of mounts. After installing the addon, all you need to do is create a macro that looks like this:

/click GoGoButton

However, if you don’t want to mess with an addon for this task, then either of the two macros mentioned above will work just fine.

Gun Show Macro

The Gun ShowUse this macro to impress your friends and dazzle the ladies. Useful for those occasions when you’ve: just topped the meters in a successful raid, owned someone in a duel, pulled off a daring flag capture in Warsong Gulch, or just think that others should recognize.

Another great opportunity to bust this one out is during downtime while raiding. Use it while the RL is distributing loot, explaining a fight, during another player’s bio break, or anytime the situation calls for it.

For this to work, you need to make sure you have at least 9 free bag spaces in your bag nearest your primary backpack (the bag just to the left of your 16 slotter).

Proper setup should involve an unsuspecting nearby female player whom you will emote…

You: /em asks you to present your tickets.
Unsuspecting Female: tickets..?
You: /s Yes, I’m now accepting tickets…
Unsuspecting female: for what..?
You: /y The Gun Show!

Get in line for the Gun Show
/script local t={3,4,5,9,10,15,19}; for k,v in pairs(t) do PickupInventoryItem(v); PutItemInBag(20); end
/flex

V. Engineering Macros

Engineers have additional on-use items associated with these equipment slots:

1 – Helmet
6 – Belt
8 – Boots
10 – Gloves
15 – Back

Glove Tinker Macro
If you have a Tazik Shocker attached to your gloves, you’re going to want to fire that sucker off as much as possible. Best way to do this is to macro it in to your shot(s) like this:

/use 10
/cast Explosive Shot
/script UIErrorsFrame:Clear()

As long as the gloves you’re wearing have an on-use engineering enchant of some sort, you never have to fiddle with the item name in the macro.

You can even combine the on-use engineering gadgets into one macro. For this example, let’s say we’re a MM Hunter who has the Hand-Mounted Pyro Rocket on our gloves, as well as the Gnomish Lightning Generator equipped in our bottom trinket slot.

/use 10
/use 14
/cast Chimera Shot
/script UIErrorsFrame:Clear()

Note: There is a 10 second burst-ability cooldown that activates when using one of the engineering DPS items. You can still combine the abilities into one macro, but they will fire off no sooner than 10 seconds apart from one another. This little mechanic was added in 3.1 to prevent engineers from gaining an unfair burst advantage in arena.

Disengage + Cloak Tinker Macro
The Disengage + Flexweave Underlay macro can really add some distance to your Disengage.

/cast Wing Clip
/cast Disengage
/use 15

IV. Equipment Macros

Each piece of gear that we wear is assigned a number, as follows:
1 = Head
2 = Neck
3 = Shoulder
4 = Shirt
5 = Chest
6 = Belt
7 = Legs
8 = Feet
9 = Wrist
10 = Gloves
11 = Finger 1
12 = Finger 2
13 = Trinket 1
14 = Trinket 2
15 = Back
16 = Main Hand
17 = Off Hand
18 = Ranged
19 = Tabard

Using the gear slot number as opposed to the actual item name is a more practical way of doing things. It not only makes for easier macro scripting, but it also allows for more freedom when swapping out gear.

The most important equipment slots to remember are:

13 – Trinket 1
14 – Trinket 2

Adding an equipslot # to your macro will activate the respective on-use trinket. For example, if you have an Ancient Petrified Seed equipped in your bottom trinket slot, you could macro it in with Bestial Wrath, like this:

/use 14
/cast Bestial Wrath

Now, let’s say your PvP gear setup uses a Ruthless Gladiator’s Badge of Cruelty in the bottom trinket slot instead. No problem, you don’t have to change a thing. Which ever trinket is located in that equipment slot, will be the one that’s used in the macro.

If you want to have more control over your trinkets, as would be the case with a PvP trinket, you can make simple macros such as these:

Top Trinket Slot
/use 13

Bottom Trinket Slot
/use 14

The nice thing about these macros is that they’ll show you which trinket you actually have equipped. Last thing you want to do is realize after the start of an arena match that you’re wearing your proc-based DPS trinket and left your PvP trinket in your backpack. Of course, this is harder to do these days with luxuries like the equipment manager.

III. Build Specific & Special Shot Macros

Bestial Wrath DPS Macro

This macro sends your pet in to attack your target and uses your major damage cooldowns. One button press will activate your trinket, cast Bestial Wrath, Kill Command & Rabid (Ferocity pets only). Combine this with Rapid Fire if it’s up, and you’ll be the talk of Recount for about 10-15 seconds.

/petattack
/use 14
/cast Bestial Wrath
/cast Rabid
/cast Kill Command
/script UIErrorsFrame:Clear()

Bestial Wrath Macro w/ Lynx Rush
If you’ve taken Lynx Rush, then you can swap Kill Command out for Lynx Rush for some nice AoE DPS.

/petattack
/use 14
/cast Bestial Wrath
/cast Rabid
/cast Lynx Rush
/script UIErrorsFrame:Clear()

Hunter Pet Macros Brawler’s Guild Burst
If you’re into the Brawler’s Arena, then you’ll want to add: /use item:98061 (Bottomless Potion of Brawler’s Deftness) to your primary burst macro, like this:

#showtooltip Bestial Wrath
/use 14
/use item:98061
/cast Bestial Wrath
/cast Rapid Fire
/cast Rabid
/script UIErrorsFrame:Clear()

Spirit Beast – Spirit Mend Macro + All-In-One Exotic Pet Ability Macro
This macro provides a little more control over your Spirit Beast’s Spirit Mend ability. Pressing it will heal you – or a mouseover target (e.g., flag carrying teammate) if you have one highlighted. It will also cast Ancient Hysteria when your Core Hound’s out, and give you a little more control over your Silithid’s and Shale Spider’s snares.

/cast [@mouseover,help][@player] Spirit Mend
/cast Ancient Hysteria
/cast [@mouseover,harm][harm] Venom Web Spray
/cast [@mouseover,harm][harm] Web Wrap
/script UIErrorsFrame:Clear()

Silencing Shot Hunter Macros

This allows for a quick target switching silence. It will look first for a hostile mouseover target – if none is highlighted, it will silence your current target.

#showtooltip Silencing Shot
/cast [@mouseover,harm][harm] Silencing Shot
You can simplify it even further if your focus target is always going to be your Silencing Shot target.

#showtooltip Silencing Shot
/cast [@focus,exists] Silencing Shot
You can also combine the two to make a mouseover macro where the focus has priority. This macro will first look for your focus target, then for a mouseover target if you have no focus target selected, then your current target if a focus and mouseover target are not available.

#showtooltip Silencing Shot
/cast [@focus,exists][@mouseover,harm][harm] Silencing Shot

Wyvern Sting Macro

This allows for quick target switching CC. It will look first for a hostile mouseover target. If none is highlighted, it will sleep your current target.

#showtooltip Wyvern Sting
/cast [@mouseover,harm][harm] Wyvern Sting
You can also apply the same rules as in the Silencing Shot macro above – configuring this macro like so:

#showtooltip Wyvern Sting
/cast [@focus,exists][@mouseover,harm][harm] Wyvern Sting
Hunter Racial MacrosIV. Racial Macros

Some of the races in WoW have traits that can provide more powerful benefits – or have some added use and versatility – when placed in a macro.

Draenei: Gift of the Naaru
This macro brings some added flexibility to the Draenei’s Gift of the Naaru racial. Pressing it will heal you – or a mouseover target (e.g., main tank, arena partner) if you have one highlighted.

/cast [@mouseover,help][@player] Gift of the Naaru
/script UIErrorsFrame:Clear()

Night Elf: Shadowmeld
I macro Shadowmeld with Spirit Walk for a nice stealth macro for when I want to surprise enemies in PvP, or if I just want to go afk and not be bothered by any npc mobs. 😉 I use a Spirit Beast with this, of course, but if you use a cat, then just swap in Prowl for Spirit Walk.

/cast Shadowmeld
/cast Spirit Walk

Orc: Blood Fury
Blood Fury is a powerful DPS boost that is best used when combined with other burst abilities such as Bestial Wrath and/or Rapid Fire, like this:

/petattack
/startattack
/cast Blood Fury
/cast Bestial Wrath
/cast Rapid Fire
/script UIErrorsFrame:Clear()

Troll: Berserking
The Troll’s Berserking racial is another great DPS cooldown. Combine it with other burst cooldowns for maximum burstage.

/petattack
/startattack
/cast Berserking
/cast Bestial Wrath
/cast Rapid Fire
/script UIErrorsFrame:Clear()

II. PvP Hunter Macros

Target Nearest Enemy Macro (Anti-Rogue/Feral Druid Macro)
Spam this macro if you think you’re about to get jacked by a Rogue or Feral Druid. It immediately makes sure your pet gets on the target ASAP, ruins your target’s opener by putting them in combat, puts up a big bouncy arrow above their head, and sends a bullet or arrow into their dome if they’re in front of you. One of my all time faves for sure.

/cleartarget
/targetenemyplayer
/startattack
/petattack
/cast Hunter’s Mark
/petassist

Scatter Shot Macro
This macro gives you precise and immediate control over your Scatter Shot target. Hitting the macro will Scatter Shot your current target – or if no target is selected – it will Scatter Shot an enemy player if your mouse is hovered over them.

#showtooltip Scatter Shot
/cast [@mouseover,harm][harm] Scatter Shot

Cancel Deterrence and Hand of Protection
Deterrence is an absolute lifesaver, but it can also prohibit a good opportunity for a killing blow – same goes for Hand of Protection. I make sure I have a way of quickly canceling out both of these spells if necessary, in the event that I need to cast a crucial attack against an opponent.

The best way to do this is to add the following lines to an ability macro:

/cancelaura Deterrence
/cancelaura Hand of Protection

I use these two commands for the following macros:

Beast Mastery Burst Macro w/ cancelaura for Deterrence and Hand of Protection:
This macro cancels any active protective auras, allowing me the instant freedom to fire up big red and kick some ass. 😉

#showtooltip Bestial Wrath
/cancelaura Deterrence
/cancelaura Hand of Protection
/petattack
/use 14
/cast Bestial Wrath
/cast Rabid
/cast Kill Command
/script UIErrorsFrame:Clear()

Kill Shot w/ cancelaura Macro:
This macro enables you to never miss a Kill Shot opportunity due to a BoP or Deterrence. Even if Kill Shot is not available it can still be used to cancel Deterrence or Blessing of Protection if needed.

#showtooltip Kill Shot
/cancelaura Deterrence
/cancelaura Hand of Protection
/cast Kill Shot
/script UIErrorsFrame:Clear()

Scare Beast Macro
This is a handy macro for fearing pesky Feral Druids, as well as hunter pets. Pressing this macro with the shift modifier will cast Scare Beast on your focus target, e.g., kitty or bear Druid. Without the modifier it casts Scare Beast on either your current target or mouseover target – if you have one.

#showtooltip Scare Beast
/cast [mod:shift][@focus] Scare Beast
/cast [@mouseover,harm][harm] Scare Beast

Versatile Bandage Macro
Use this macro to heal your mouseover target, or yourself – if no target is selected. Just swap in the type of bandage you have in your inventory.

/use [@mouseover,help][@player] Dense Embersilk Bandage

Camouflage Toggle
This is a really simple macro you can use to toggle Camouflage on or off – rather than clicking on the buff to cancel it. If Camouflage is not active, it puts you in stealth – if Camo is active, then it cancels it.

I like to use my mouse exclusively for movement, so I don’t like having to “click” on any skills or buffs. This macro is handy for canceling Camo real quick before you’re about to grab a flag, for example.

#showtooltip Camouflage
/cancelaura Camouflage
/cast Camouflage
/script UIErrorsFrame:Clear()

All-In-One Pet Survival Macro
This macro combines all of the various pet abilities which help to keep it alive – or in the case of a Ferocity pet – to even resurrect it. It’s more of an emergency macro, so don’t use it for routine Mend Pets — only use it if your pet is on the verge of getting focused down – or if you have a Ferocity pet with Heart of the Phoenix – this macro can bring them back up with one click.

Pressing it will put your pet in Cower (reducing incoming damage by 40% for 6 sec) and throw a Mend Pet up. It will also cast Last Stand if you have a Tenacity pet out – or – Bullheaded if you have a Cunning pet out. If you have a Ferocity Pet it will add Lick Your Wounds or cast Heart of the Phoenix if your pet’s dead.

/cast Cower
/cast Last Stand
/cast Bullheaded
/cast Heart of the Phoenix
/cast Mend Pet
/script UIErrorsFrame:Clear()

Quick Pet Safety + Dismiss Pet
This is a handy macro for pulling your pet back if they’re in danger. If Dash is needed to get them out of harm’s way quickly, then press the alt key as well. I’ve also added Dismiss Pet to this macro to save a little action bar space. Pressing the shift key will Dismiss your current pet.

/cast [mod:shift] Dismiss Pet
/cast [mod:alt] Dash
/petpassive
/petfollow
/script UIErrorsFrame:Clear()

Guard Dog Macro
I like using this while I’m on the run. It puts my pet in defensive mode and throws out the PetMoveTo target circle. Not a hugely necessary macro, but I like to keybind all of my abilities if possible. It’s so much better being free to use your mouse for all movement; not having to ‘click’ on any abilities.

/petmoveto
/petdefensive

Healthstone / Potion Macro
This macro will use a Healthstone if you have one, or a healing potion if you do not. Substitute in the appropriate healing potion type. I rarely use health potions in BGs, especially now since they’re so costly, but a handy macro nonetheless.

/use Healthstone
/use Runic Healing Potion
/script UIErrorsFrame:Clear()

Battle Standard Macro
I’ve been toting my Battle Standards around for years, but I seldom use them, which is a shame. This is partly because I often forget, but also because using one always meant opening my inventory to click it.

So, I decided to make a super simple macro that would plant either my Stormpike Battle Standard (if in AV) or my Alliance Battle Standard (if in any other BG) with one key press. Now I use them all the time. 🙂

/use Stormpike Battle Standard
/use Alliance Battle Standard

Basic Pet Attack
This macro just makes sure that your pet is in defensive mode and on follow when it goes to attack.

/petdefensive
/petfollow
/petattack

All-In-One-Pet-Care Macro
This macro covers four very important abilities for use with your pet. It revives your pet if it’s dead, calls it if it’s alive but not out, casts Mend Pet if it needs heals, or it can perform a quick res with Heart of the Phoenix (Ferocity-only). If your pet is dead and not in line of sight, then hold down the shift key to revive it. This is an essential Hunter macro.

/cast [mod:shift] Revive Pet; [mod:alt] Heart of the Phoenix; [@pet,dead] Revive Pet; [nopet] Call Pet 1;
Mend Pet

Master’s Call Macro
This adds an additional mouseover effect for Master’s Call, allowing for a quick freedom for a teammate or party member. If no friendly player is highlighted, then it just activates Master’s Call as normal.

/cast [@mouseover,help][@player] Master’s Call

Roar of Sacrifice Macro
Functions just like the Master’s Call macro, but for Roar of Sacrifice.

/cast [@mouseover,help][@player] Roar of Sacrifice

Pet Feeding
With pet happiness a thing of the past, there’s not much reason to feed pets anymore apart from a quick Feed Pet heal now and then. At any rate, here are a few Feed Pet macros if you wanna use ‘em…

Super Simple Feed Pet Macro
This is just a simple one-click pet feed macro. Paste in the food type and you’re good to go.

/cast Feed Pet
/use Roasted Quail

Feed Pet Macro for Multiple Pet and Food Types
This is a handy macro for easy pet feeding, regardless of which pet you have out at the time. Just set it and forget it. Check out Petopia’s diet chart to see what sort of chow your pet likes.

/cast Feed Pet
/use [pet:Wind Serpent] Blackened Trout
/use [pet:Gorilla] Telaari Grapes
/use [pet:Wolf] Ravager Dog

Useful Raiding and PvE Hunter Macros

The assist and Misdirection macros default to a predetermined focus (usually the main tank). Since it may be necessary to switch focus targets multiple times during an encounter – due to taunt switches, debuff stacks, tank dying, etc… it is a good idea to have your focus target assigned to a keybind. I use F… it’s easy to remember.

Simple Misdirection
This casts Misdirection onto your friendly focus target (main tank) without deselecting your current target. If you have no focus target (i.e., assist) selected, it will cast Misdirection onto your pet.

/cast [@focus,exists][@pet,exists] Misdirection

Simple Assist
As long as you have a focus selected – such as your main tank – this macro will ensure that you hit whatever they’re hitting. If you haven’t assigned a focus then this macro will have you assist your pet.

/assist [@focus,exists][@pet,exists]
/startattack
/petassist

Simple Pull Macro
This is a basic macro that you can use while out farming or questing. One press will cast a Hunter’s Mark on your target, send your pet in to attack and start your auto-shot.

/petattack
/cast Hunter’s Mark
/startattack

Target Nearest Enemy Macro with Hunter’s Mark
This macro is similar to the one above, only it doesn’t need a target first. Presisng it will automatically target the mob closest to you, send your pet on it, throw up a Hunter’s Mark, start your auto-attack and put your pet into an assist stance.

/targetenemy
/startattack
/petattack
/cast Hunter’s Mark
/petassist

Rapid Fire Burst Macro
This macro adds some extra muscle behind Rapid Fire. It activates your bottom on-use DPS trinket (replace 14 with 13 if you keep your on-use trinkets in the top slot) and casts Rapid Fire at the same time.

#showtooltip Rapid Fire
/use 14
/cast Rapid Fire
/script UIErrorsFrame:Clear()
Add in things like Blood Fury and Bestial Wrath – if you have them – for even more added burst.

#showtooltip Rapid Fire
/use 14
/cast Blood Fury
/cast Bestial Wrath
/cast Rapid Fire
/cast Rabid
/script UIErrorsFrame:Clear()

Tranquilizing Shot
This macro will dispel a buff or enrage effect from your hover-over target, or your current target if no other targets are highlighted. This is useful for getting off a quick dispel on a secondary target, while maintaining pressure on your current target.

#showtooltip Tranquilizing Shot
/cast [@mouseover,harm][harm] Tranquilizing Shot

Aspect Switching

Hunter Aspects can be combined into one button press to allow for easy alternating between them. Here are a few examples of some common uses:

Cheetah to Pack w/ Beast Modifier
One button speed macro. One press puts you in Cheetah – click it again to activate Pack. Add an alt click and you’re in Beast.

/cast [mod:alt] Aspect of the Beast; Aspect of the Cheetah
/cast Aspect of the Pack